Parlons Arduino > JMRI et Arduino
Carte 24 entrées 48 sorties pour JMRI
nopxor:
C'est une carte pilotée par un Arduino Nano et qui est l'équivalent d'une carte SMINI-C/MRI.
https://www.utrainia.com/65-arduinocmri-and-rs485
Elle peut commander par exemple des aiguillages, des éclairages ou des feux de signalisation.
On peut y connecter des modules de détection de cantons ou des boutons.
Elle est reliée au PC par un bus RS485 à 2 fils grâce à un adaptateur USB-RS485 (1€ sur Ebay)
On peut connecter ensemble plusieurs de ces cartes à JMRI en les chainant par ce bus.
Chaque carte est identifiée par un numéro de node dans JMRI.
http://jmri.org/help/fr/html/hardware/cmri/CMRI.shtml#iobits
La carte utilise 6 CI 74HC595 pour les 48 sorties et 3 CI 74HC165 pour les 24 entrées (pull-upées).
Ces registres à décalage 8 bits sont chainés et reliés par 2 x 3 fils au Nano.
J'ai utilisé Eagle pour la CAO du schéma et du PCB.
J'ai fait fabriquer par JLCPCB un PCB double face compact 100 x 100 mm. (2$ les 10 ! + 11€ de port)
Je fournis les fichiers en pièce jointe.
Pour commander des PCB chez JLCPCB il suffit d'uploader sur leur site Le fichier Arduino-CMRI_Gerber.zip
https://jlcpcb.com
Le programme du Nano est ultra simple grâce aux bibliothèques CMRI et Auto485 disponibles sur le site utrainia.
Il suffit de préciser le numéro de node affecté à la carte.
--- Code: ---/**
* C/MRI -> JMRI via RS485
* =======================
* Sets up an SMINI 24 inputs, 48 outputs with an Arduino Nano.
* Uses an RS485 bus to transparently talk support multiple ArduinoCMRI nodes on one bus.
* By passing in an Auto485 object to the CMRI constructor, we are able to automatically
* control the DE and RE pins on our RS485 bus transceiver.
* The PC with JMRI has an USB-RS485 adapter connected to the bus.
*
* IN control:
* Nano pin: 74HC165 pin:
* 9 LATCH -> 1
* 13 SCK -> 2
* 12 MISO -> 9
*
*
* OUT control:
* Nano pin: 74HC595 pin:
* 6 verrou -> 12
* 7 donnee -> 14
* 8 horloge -> 11
*
*
* Change the CMRI_ADDR for each board. Each node must have its own address.
* ====================================
**/
#include <Auto485.h>
#include <CMRI.h>
#include <SPI.h>
#define CMRI_ADDR 0 // select the CMRI node address
#define DE_PIN 2 // Arduino pin 2 -> MAX485 DE and RE pins
// pin 74HC165
const byte LATCH = 9;
// pins 74HC595
const byte verrou = 6;
const byte donnee = 7;
const byte horloge = 8;
Auto485 bus(DE_PIN); // RS485 bus transceiver
CMRI cmri(CMRI_ADDR, 24, 48, bus); // sets up an SMINI. SMINI = 24 inputs, 48 outputs
void setup() {
bus.begin(9600, SERIAL_8N2); // open the RS485 bus at 9600bps
pinMode(verrou, OUTPUT);
pinMode(donnee, OUTPUT);
pinMode(horloge, OUTPUT);
SPI.begin (); // serial data protocol used to control 74HC165
pinMode (LATCH, OUTPUT);
digitalWrite (LATCH, HIGH);
}
void loop() {
// 1: main processing node of cmri library
cmri.process();
// 2: update output
digitalWrite(verrou, LOW); // on commence par mettre le verrou
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(5)); // on envoie la sixieme donnée d'abord
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(4)); // on envoie la cinquieme donnée ensuite
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(3)); // on envoie la quatrieme donnée ensuite
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(2)); // on envoie la troisieme donnée ensuite
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(1)); // on envoie la seconde donnée ensuite
shiftOut(donnee, horloge, MSBFIRST, cmri.get_byte(0)); // et on envoie la première donnée
digitalWrite(verrou, HIGH); // et on relache le verrou pour mettre à jour les données
// 3: update inputs
digitalWrite (LATCH, LOW); // pulse the parallel load latch
delay(1); // wait while data loads
digitalWrite (LATCH, HIGH);
cmri.set_byte(0, ~(SPI.transfer(0)));
cmri.set_byte(1, ~(SPI.transfer(0)));
cmri.set_byte(2, ~(SPI.transfer(0)));
}
--- Fin du code ---
Il y a 2 jumpers sur la carte reliés à RX et TX.
Il faut les enlever pour la programmation du Nano et les remettre après celle-ci.
L'alimentation 5V se fait sur un bornier.
Il faut la déconnecter lors de la programmation du Nano par la prise USB.
Il y a 2 borniers de connection au bus RS485 pour faciliter le chainage des cartes.
Pas besoin de résistances de terminaison de 120 ohm pour le RS485 lorsque les liaisons ne font que quelques metres.
A noter qu'une carte SMINI en kit coute 100€ (160€ assemblée).
Celle-ci devrait vous couter moins de 10€ !
La liste des composants est dans le dossier Arduino-CMRI_Eagle.zip.
Ils se trouvent couramment sur Ebay.
Les connecteurs sont au pas de 3.5mm comme ceux-là:
https://www.ebay.fr/itm/262957982206
nopxor:
Les sorties peuvent délivrer jusqu'à 35mA, mais chaque circuit 74HC595 qui comporte 8 sorties peut délivrer 70mA au maximum.
Ci-joint les fichiers Eagle:
Dominique:
Bravo ;D
C'est du professionnel !
msport:
Superbe réalisation pour les utilisateurs du protocole C/MRI !
Et la mise à disposition des fichiers Eagle mérite d'être saluée.
L'occasion de rappeler que JMRI prend en charge DCC++, mais dont la partie signalisation n'est peut-être pas la plus utilisée.
nopxor:
Bonjour,
Notre ami Marcel (CATPLUS) souhaitait pouvoir tirer d'avantages de courant sur les sorties.
J'ai donc réalisé une carte booster à base de 3 ULN2803A qui se connecte directement de chaque coté des sorties de la carte principale.
Ce sont des circuits avec 8 sorties Darlington à collecteur ouvert pouvant fournir 500 mA (par sortie).
Les sorties du booster sont sur borniers aux pas de 5 mm.
Ci-joint le zip des fichiers Gerber à uploader chez le fournisseur de PCB.
Et les fichiers Eagle.
Navigation
[#] Page suivante
Utiliser la version classique